XYplorer Beta Club

Code: Select all

    $tmpIni = "%TEMP%\~XYplorer.ini";
    savesettings 1, $tmpIni;

    $favorites = getsectionlist("Favorites", $tmpIni);
    $favorites = regexreplace($favorites, "^Count=\d+\r?\n");
    $favorites = regexreplace($favorites, "(^Fav\d+=[""]|[""]$)");
    $favorites = regexreplace($favorites, "^(.+?)$", "$1|$1|$1" . <crlf>);
    end (!$favorites), "No favorite folder(s) defined, aborted!";

    $sel = popupmenu($favorites, 6:=<crlf>, 7:="|");
    if ($sel) {
        if (!get("#800")) { #800; }
        focus "PI";
        goto $sel;
    }

Code: Select all

    /*
    Normal:
    E:\VB-Don\TestFiles\Media

    Captions:
    "Transparent PNGs" E:\VB-Don\TestFiles\Media\ARGB 32bit\

    Caption with custom icon:
    "caption|[icon spec]" location
    "caption|Kiss.ico" location
    "caption|C:\WINDOWS\notepad.exe" location
    "caption|:dice" location
    "caption|%winsysdir%\shell32.dll /160" location
    */

    // Go to favorite folders in the other pane
    $tmpIni = "%TEMP%\~XYplorer.ini";
    savesettings 1, $tmpIni;

    $tmpFavs = getsectionlist("Favorites", $tmpIni);
    $tmpFavs = regexreplace($tmpFavs, "^Count=\d+\r?\n");
    $tmpFavs = regexreplace($tmpFavs, "(^Fav\d+=[""]|[""]$)");

    $newFavs = "";
    foreach($fav, $tmpFavs, <crlf>, "e") {
        // Has '"' in it
        if (strpos($fav, '"') != -1) {
            $prefix = gettoken($fav, 2, '"', "t");
            $path   = gettoken($fav, 3, '"', "t");

            // Has an icon
            if (strpos($prefix, "|") != -1) {
                $title    = gettoken($prefix, 1, "|", "t");
                $icon     = gettoken($prefix, 2, "|", "t");
                $newFavs .= $title . "|" . $path . "|" . $icon . <crlf>;
                continue;
            }
            $newFavs .= $prefix . "|" . $path . "|" . $path . <crlf>;
        } else {
            $newFavs .= $fav . "|" . $fav . "|" . $fav . <crlf>;
        }
    }
    $newFavs = trim($newFavs, <crlf>, "R");
    end (!$newFavs), "No favorite folder(s) defined, aborted!";

    $sel = popupmenu($newFavs, 6:=<crlf>, 7:="|");
    if ($sel) {
        if (!get("#800")) { #800; }
        focus "PI";
        goto $sel;
    }