XYplorer Beta Club

Code: Select all

"&Find a Command, Execute  (a.k.a FACE) : face"
	// This displays XY's list of commands and executes the selected item.

	Sub('_checkPerms');
	Perm $CMD_LIST; // Ensure it is available in current scope.

	$ret = InputSelect('Select a command to call...', "$CMD_LIST", "<crlf>", 4, '');

	if ($ret == '') {
		Status 'No command selected.', 'CD0000', 'alert';
	} else {
		$cmd = GetToken($ret, 1, "<tab>");		// Command
		$cid = GetToken($ret, 2, "<tab>");		// Command's ID

		if ($cid UnLikeI '[#]#*') {
			Status "Error parsing selected command: $cid", 'CD0000', 'alert';
		} else {
			Status "Calling: $cmd", '0000CD', 'progress';
			Load("$cid;",,'s');
		}
	}

"- : _-" //--------------------------------------------------------------------


"&Check for Command List Cache : _checkPerms"
	// This attempts to minimize the pain of getting the command list
	// by storing it as a permanent variable.
	//
	// Updates are only forced when XY's version changes, which means that it
	// is possible for the list of commands from the User menu to become stale,
	// especially if permanent variables are retained across sessions.

	Perm $CMD_LIST, $CMD_LIST_VERSION;

	if ($CMD_LIST_VERSION != "<xyver>" OR ! IsSet($CMD_LIST) OR $CMD_LIST == "") {
		Status 'Retrieving command list...', '0000CD', 'progress';

		$cb = "<clipboard>";
		#705; // Help / Make List of Commands...
		$CMD_LIST = "<clipboard>";
		$CMD_LIST_VERSION = "<xyver>";
		CopyText "$cb";
	}
	Status 'Command list cached...', '0000CD', 'ready';


"&Refresh Command List Cache : _force"
	// Clears the cached command list and retrieves it anew.

	Perm $CMD_LIST;
	Unset $CMD_LIST;
	Sub('_checkPerms');