XYplorer Beta Club

Code: Select all

/* 06.08.2011, swap the names of two files. Leave the extension alone
   ::load "<xyscripts>\SwapFileNames.xys";

   Remarks: Two files or two folders on one pane must be selected
*/
	setting('BackgroundFileOps', 0);

	// Get current path
	$CurrentPath = "<curpath>";

	// Get selected items
	$SelectedFilesOrFolders = get("SelectedItemsPathNames", "|");

	// If nothing || one file / folder || more than two files / folders are selected, abort script
	end (getinfo("CountSelected") <= 1 || getinfo("CountSelected")  >= 3), "You haven't selected a pair of files or folders, aborted!";

	// Check if a single | multiple files, a folder or a drive is selected
	// False = folder | True = file | Drive = drive
	$CheckFileOrFolder = report("{Dir False|True|Drive}|", 1);
	$CheckItem1 = gettoken("$CheckFileOrFolder", 1, "|");
	$CheckItem2 = gettoken("$CheckFileOrFolder", 2, "|");
	end($CheckItem1 != $CheckItem2), "Your selected items are not a file or folder pair!, aborted";

	if("$CheckItem1" == "True" && "$CheckItem2" == "True") {
		// A pair of files is selected
		// Get the base name of the two files
		$FirstSelectedItem = gettoken("$SelectedFilesOrFolders", 1, "|");
		$FileBaseName1 = regexreplace($FirstSelectedItem, "(.*\\)(.*(?=\.))(.*)", "$2");
		$Extension1 = regexreplace($FirstSelectedItem, "(.*\.)(.*)", "$2");

		$SecondSelectedItem = gettoken("$SelectedFilesOrFolders", 2, "|");
		$FileBaseName2 = regexreplace($SecondSelectedItem, "(.*\\)(.*(?=\.))(.*)", "$2");

		// First file has to get a temp name before the real rename occurs if the file extension is the same!
		$TempFileBaseName1 = ~TempFileName1;
		$NewFirstSelectedItem = $CurrentPath . "\" . $TempFileBaseName1 . "." . $Extension1;

		// Rename them
		rename s, "$FileBaseName1/$TempFileBaseName1", , "$FirstSelectedItem";
		rename s, "$FileBaseName2/$FileBaseName1", , "$SecondSelectedItem";
		rename s, "$TempFileBaseName1/$FileBaseName2", , "$NewFirstSelectedItem";

	} else {
		// A pair of folders is selected
		// Get the base name of the two folders
		$FirstSelectedItem = gettoken("$SelectedFilesOrFolders", 1, "|");
		$FolderBaseName1 = regexreplace($FirstSelectedItem, "(.*\\)(.*)", "$2");

		$SecondSelectedItem = gettoken("$SelectedFilesOrFolders", 2, "|");
		$FolderBaseName2 = regexreplace($SecondSelectedItem, "(.*\\)(.*)", "$2");

		// First folder has to get a temp name before the real rename occurs
		$TempFolderBaseName1 = ~TempFolderName1;
		$NewFirstSelectedItem = $CurrentPath . "\" . $TempFolderBaseName1;

		// Rename them
		rename s, "$FolderBaseName1/$TempFolderBaseName1", , "$FirstSelectedItem";
		rename s, "$FolderBaseName2/$FolderBaseName1", , "$SecondSelectedItem";
		rename s, "$TempFolderBaseName1/$FolderBaseName2", , "$NewFirstSelectedItem";
	}