XYplorer Beta Club

Code: Select all

    // These files must exist in "<xynewitems>"!
    $templateFiles = <<<>>>
Excel document.xlsx
PowerPoint document.pptx
Word document.docx
    >>>;

    // $default = "a.docx<crlf>b.xlsx<crlf>c.pptx<crlf>d.txt";
    $default = "";
    $files   = input("Enter file name(s) to create...", 2:=$default, 3:="m", 5:=600, 6:=400);


    // Check which template files really exist
    $existingTemplateFiles    = "";
    $nonExistingTemplateFiles = "";
    foreach($templateFile, $templateFiles, <crlf>, "e") {
        $file = <xynewitems> . "\" . $templateFile;
        $ext  = gpc($file, "ext");
        if (exists($file) == 1) { $existingTemplateFiles    .= $ext . "|" . $templateFile . <crlf>; }
        else                    { $nonExistingTemplateFiles .= $ext . "|" . $templateFile . <crlf>; }
    }

    setting "BackgroundFileOps", 0;

    // All files can be created, make exceptions for standard Office files: doc(x), ppt(x), xls(x)
    $notCreated = "";
    $officeExts = "|doc|docx|ppt|pptx|xls|xlsx|";
    foreach($file, $files, <crlf>, "e") {
        $ext = gpc($file, "ext");

        // Office file(s)
        if (strpos($officeExts, "|" . $ext . "|") != -1) {
            $matchNonExisting = regexmatches($nonExistingTemplateFiles, "^" . $ext . "\|");
            if ($matchNonExisting) { $notCreated .= $file . <crlf>; continue; }

            // Get the belonging template file, copy it over, rename it
            $templateFile = regexmatches($existingTemplateFiles, "^" . $ext . "\|.+?$");
            $templateFile = <xynewitems> . "\" . gettoken($templateFile, 2, "|");

            $dstFile = <curpath> . "\" . $file;
            if (exists($dstFile) != 1) { copyitem $templateFile, $dstFile; }

        // All other file types
        } else {
            new(<curpath> . "\" . $file, "file");
        }
    }
    if ($notCreated) {
        $msg  = "NOT created, template file does not exist!";
        $msg .= <crlf> . strrepeat("=", strlen($msg)) . <crlf>;
        text  $msg . $notCreated;
    }