XYplorer Beta Club

Code: Select all

    $dst = "<xydata>\Favorites";
    if (exists($dst) != 2) { new($dst, "dir"); }

    $favFiles = listfolder($dst, "*.txt", 1+4, <crlf>);
    $mouseBtn = <get trigger mousebtn>;

    // Left click (load profile)
    if ($mouseBtn == 1) {
        end ($favFiles == ""), "No profile(s) yet, aborted!";

        $menu = replace($favFiles, ".txt");
        $sel  = popupmenu($menu, 6:=<crlf>);
        if ($sel) {
            $cntFiles   = 0;
            $cntFolders = 0;
            $favFile    = $sel . ".txt";
            $content    = readfile("$dst\$favFile", , , 65001);
            $files      = regexmatches($content, "^\[Files\](\s|\S)+?^\[");
            if ($files) {
                $files    = trim(regexreplace($files, "^\[.*?(\r?\n|$)"), <crlf>);
                $cntFiles = gettoken($files, "count", <crlf>);
                favs("f", $files, , "s");
            }
            $folders = regexmatches($content, "^\[Folders\](\s|\S)+");
            if ($folders) {
                $folders    = trim(regexreplace($folders, "^\[.+?\](\r?\n)"), <crlf>);
                $cntFolders = gettoken($folders, "count", <crlf>);
                favs("d", $folders, , "s");
            }
            if ($files == "" && $folders == "") {
                status "No favorites in profile, aborted!", "8B4513", "stop";
                end true;
            }
            status ($cntFiles + $cntFolders) . " favorites loaded from " . quote($sel);
        }

    // Right click (save profile)
    } elseif ($mouseBtn == 2) {
        // Show all existing profile (files) and one entry to create a new one
        $favFiles = replace($favFiles, ".txt");

        $menu = "Save as a new profile";
        if ($favFiles != "") { $menu .= <crlf> . "-" . <crlf> . $favFiles; }

        $files   = favs("f");
        $folders = favs("d");
        end ($files == "" && $folders == ""), "No favorites defined, aborted!";

        $sel = popupmenu($menu, 6:=<crlf>);
        if ($sel == "Save as a new profile") {
            $fileName = input("Enter filename, WITHOUT extension!", , "Work");
            end ($fileName == ""), "Empty name entered, aborted!";

            $fileName .= ".txt";
            step; // DEBUG
            if (exists("$dst\$fileName") == 1) {
                if !(confirm("Profile already exists, overwrite?", , , 1+32)) { end true; }
            }
            WriteFavFile("$dst\$fileName", $files, $folders);

        } elseif ($sel != "") {
            $fileName = $sel . ".txt";
            WriteFavFile("$dst\$fileName", $files, $folders);
        }
    }

function WriteFavFile($file, $favFiles, $favFolders) {
    $content = "[Files]" . <crlf> . $favFiles . <crlf 2> . "[Folders]" . <crlf> . $favFolders;
    writefile($file, $content, , "utf8");
}