XYplorer Beta Club

Code: Select all

    $lcaseHash = true;

    $files = <get SelectedItemsPathNames>;
    end (!$files), "No file(s) selected, aborted!";

    $menu = <<<>>>
        Add CRC32 hash(es)|add|:tagsadd
        Remove CRC32 hash(es)|remove|:tagsrmv
    >>>;
    $menu = regexreplace($menu, "^[ \t]+");

    $sel = popupmenu($menu, 6:=<crlf>, 7:="|");
    if ($sel) {
        if     ($sel == "add")    { HandleCRC32($files, "add", $lcaseHash);    }
        elseif ($sel == "remove") { HandleCRC32($files, "remove", $lcaseHash); }
    }


function HandleCRC32($files, $cmd="add", $lcase=true) {
    showstatus 0;

    foreach($file, $files, <crlf>, "e") {
        if (exists($file) == 2) { continue; }
        $base = gpc($file, "base");
        $ext  = gpc($file, "ext");

        if ($cmd == "add") {
            if (regexmatches($base, "-[a-f0-9]{8}$")) {
                $base = regexreplace($base, "-[a-f0-9]{8}$");
            }
            status "Calculating hash: " . gpc($file, "file"), , "progress";
            $hash = hash("crc32", $file, 1);
            if ($lcase) { $hash = recase($hash, "l"); }
            renameitem($base . "-" . $hash . "." . $ext, $file);

        } elseif ($cmd == "remove") {
            if (regexmatches($base, "-[a-f0-9]{8}$")) {
                $base = regexreplace($base, "-[a-f0-9]{8}$");
                renameitem($base . "." . $ext, $file);
            }
        }
    }
    status "All done...";
}