XYplorer Beta Club

Code: Select all

    // Get file(s) & folder(s) without path
    $files   = listpane(, , 1+4, <crlf>);
    $folders = listpane(, , 2+4, <crlf>);

    // Loop over all file(s) (and try to create blocks with the same prefix)
    while ($files) {
        // Get prefix
        $first  = gettoken($files, 1, <crlf>);
        $prefix = substr($first, 0, 10);

        // If $prefix == $first, remove it from the $files list without further processing
        if ($prefix == $first) {
            $files = regexreplace($files, "^" . $prefix . ".*?(\r?\n|$)");
            continue;
        }

        // Get all other file(s) with the same prefix
        $matchFiles = regexmatches($files, "^" . $prefix . ".*?(?=\r?\n|$)", <crlf>);

        // Move into which folder?
        $matchFolder = gettoken(regexmatches($folders, "^" . $prefix . ".*?(?=\r?\n|$)", <crlf>), 1, <crlf>);
        if (!$matchFolder) { $matchFolder = $prefix; }

        // Remove them from the $files list
        $files = regexreplace($files, "^" . $prefix . ".*?(\r?\n|$)");

        // Move them
        moveto "<curpath>\$matchFolder", $matchFiles, , 2, 2, 4;
    }