XYplorer Beta Club

Code: Select all

"RenameRandom : renamerandom"
  // Renames current selected items to random names.
  /*** user-configurable options ***/
  $report = 1;   /* whether to generate a report of renames; 1 or 0 */
  $maxLen = 16;  /* max length of name; 0 < $maxLen < 256 */
  $minLen =  8;  /* min length of name; 0 < $minLen <= $maxLen */
  $pool   = "abcdefghijklmnopqrstuvwxyzABCDEFGHIJKLMNOPQRSTUVWXYZ0123456789-=+_'@$%&^~*#[](),.";
  // $pool = character pool for generating random names
  /*** end of user-configurable options ***/
  $pool   = replacelist($pool, '\/:*?"<>|', '');                               // remove disallowed characters
  $len    = gettoken($pool, 'count', ':');                                     // length of character pool
  $maxLen = ($maxLen > 255)     ?     255 : $maxLen ;                          // sanitize max length
  $minLen = ($minLen < 1)       ?       1 : $minLen ;                          // sanitize min length
  $maxLen = ($maxLen < $minLen) ? $minLen : $maxLen ;                          // sanitize min-max length range
  if $report { $report = ''; } else { unset $report; }                         // init reporting
  $sel    = get("SelectedItemsPathNames", '|');                                // items to rename, current selection
  // $sel    = formatlist(replace(readfile(<curitem>), <crlf>, '|'), 'e');        // items to rename, current selection
  $maxNameLen = 0;
  foreach ($item, $sel) {                                                      // get length of longest itemname in $sel
    $itemNameLen = strlen(gpc($item, 'file'));
    $lastMaxLen =($itemNameLen > $lastMaxLen) ? $itemNameLen : $lastMaxLen;
    $maxNameLen = $lastMaxLen;
  }
  foreach ($item, $sel) {
    $randName = gpc($item, 'file');
    while exists(gpc($item, 'path') . '\' . $randName) {                       // generate a unique random name
      $randLen  = rand($minLen, $maxLen);                                      // random name length for current loop item
      $randName = get('rs', $randLen, $pool);                                  // generate a random name
    }
    $randName = renameitem($randName, $item, 3);                               // perform the rename
    wait 1;
    if isset($report) {                                                        // generate report
      $oldName = gpc($item, 'file');
      $report = $report . $oldName .
                strrepeat(' ', $maxNameLen-strlen($oldName)) . " -> " . 
                $randName . <crlf>;
    }
  }
  if isset($report) { text $report; }                                          // display report if available
  status "RenameRandom: finished";

Code: Select all

   + SC get got a new named argument "rs" to return a random string.
      Syntax: get("rs", [length=8] [characters="abcdefghijklmnopqrstuvwxyzABCDEFGHIJKLMNOPQRSTUVWXYZ0123456789"])
        length: Length (character count) of the returned string.
                Defaults to 8.
                You can also give a min and a max value separated by "-" for a random length, e.g. "8-12".
                There is an arbitrary maximum length of 32768, just to protect you from yourself.
        characters: Characters from which the returned string is built.
                Defaults to "abcdefghijklmnopqrstuvwxyzABCDEFGHIJKLMNOPQRSTUVWXYZ0123456789".
        return: Random string.
      Examples:
        echo get("rs");
        echo get("rs", 8, "abcdefghijklmnopqrstuvwxyzABCDEFGHIJKLMNOPQRSTUVWXYZ0123456789");
        echo get("rs", "4-12", "abc");
        echo get("rs", 12, ". ");
      Of course, also the variable <get ...> supports it:
        echo <get rs>;
        echo <get rs 8 abcdefghijklmnopqrstuvwxyzABCDEFGHIJKLMNOPQRSTUVWXYZ0123456789>;
        echo <get rs 4-12 abc>;
        echo <get rs 12 ". ">;
   >  Tip: Now you can use <get rs> in Batch Rename to rename a file to some random string.

Code: Select all

<get rs 16> /e