XYplorer Beta Club

Code: Select all

"Calculate Length"
	// Retrieve the lengths as a mathematical equation.
	// You may need to adjust the '{prop:*Length}' for your system.
	Global $G_DURATION = Report('+{prop:*Length}', 0 /*use 1 for selection instead*/, 0);

	// Remove items which didn't have a length.
	$G_DURATION = FormatList($G_DURATION, 'tue', '+');

	// Expand 'hh:mm:ss' to 'hh*60*60+mm*60+ss' so we calculate total seconds.
	$G_DURATION = RegexReplace($G_DURATION, '(\d\d):(\d\d):(\d\d)', '$1*60*60+$2*60+$3');

	// Do the math.
	$G_DURATION = eval($G_DURATION);

	Sub '_formatDuration';

	Echo $G_DURATION;

"Format Duration in Seconds : _formatDuration"
	Global $G_DURATION;
	$Secs = $G_DURATION;

	// Just stealing Don's code since I don't feel like doing this right now:
	// Src: http://www.xyplorer.com/xyfc/viewtopic.php?p=57847#p57847
	// format duration given in seconds
	$DAYS_PER_YEAR = 365.25;
	$HOURS_PER_DAY = 24;
	$MINS_PER_HOUR = 60;
	$SECS_PER_MIN = 60;
	$duration = "";

	$Mins = $Secs \ $SECS_PER_MIN;
	$Hours = $Mins \ $MINS_PER_HOUR;
	$Days = $Hours \ $HOURS_PER_DAY;
	$Years = $Days \ $DAYS_PER_YEAR;
	If ($Years > 0) {
		$duration = $Years . "y";
	}
	$Days = $Days % $DAYS_PER_YEAR;
	If ($Days > 0) {
		$duration = $duration . " " . $Days . "d";
	}
	$Hours = $Hours % $HOURS_PER_DAY;
	If ($Hours > 0) {
		$duration = $duration . " " . $Hours . "h";
	}
	$Mins = $Mins % $MINS_PER_HOUR;
	If ($Mins > 0) {
		$duration = $duration . " " . $Mins . "min";
	}
	$Secs = $Secs % $SECS_PER_MIN;
	If ($Secs > 0) {
		$duration = $duration . " " . $Secs . "sec";
	}

	$G_DURATION = $duration;

Code: Select all

Text Report("{prop:*Length}<crlf>", 1);

Code: Select all

Global $G_DURATION = Report('+{prop:*Length}', 0 );