XYplorer Beta Club

Code: Select all

CEA_ListRightClickOnWhite_Script=::load "D:\Tools\XYplorer\Scripts\vTB.xys"; 

Code: Select all

CEA_ListRightClickOnWhite_Script=load "D:\Tools\XYplorer\Scripts\vTB.xys"

Code: Select all

/*#############################################################################\
TreeRightClickOnWhite.xys

Script versions of the various tweaks available for CEA_TreeRightClickOnWhite as
of March 9, 2015.

Suggested INI tweaks:
CEA_TreeRightClickOnWhite=6
CEA_TreeRightClickOnWhite_Script=::Load 'CEA\TreeRightClickOnWhite';

This makes all of the original tweaks available and allows you to change the
behavior without restarting XY.


[ABOUT]
Author    = TheQwerty
Version   = 1.0
Date      = 2015-03-09 13:13z
Requires  = XYplorer v14.80.0245

[]
\#############################################################################*/


/*******************************************************************************
** Show Menu
**   Single entry point into script to easily modify the displayed menu.
*******************************************************************************/
"Show Menu||1 : showMenu"
	$menu = <<<MENU
_favs
_favFiles
_favsFull
-
_drives
_drivesSpecial
-
_tabsAll
_tabsPane
MENU;
	$menu = RegexReplace($menu, '(\r?\n)+', ';');

	Load '*', $menu;


"0 <get MenuCaption 550>|:favs|1 : _favs"
	#550; // Favorites | Favorite Folders | - submenu -


"1 Favorites Main Menu : _favsFull"
	popupmainmenu 'favorites';


"2 <get MenuCaption 526>|:drives : _drives"
	#526; // Go | Drives...


"3 <get MenuCaption 526> + <get MenuCaption 551> : _drivesSpecial"
	// Build drive list
	$drives = '';
	foreach ($drive, Get('Drives')) {
		$drives = <<<DRIVE
$drives
"$drive - <get DriveName $drive 1>|$drive" goto '$drive';
DRIVE;
	}

	$script = <<<SCRIPT
"%computer%|%computer%" goto '%computer%';
-
%desktop%
%personal%
%username%
-
$drives
-
"%net%|%net%" goto '%net%';
"%recycler%|%recycler%" goto '%recycler%';
SCRIPT

	Load $script,, 's';


"4 <get MenuCaption 690>|:tablist : _tabsAll"
	#690; // Panes | Tabs | - submenu -


"5 <get MenuCaption 564>|:favfiles : _favFiles"
	#564; // Favorites | Favorite Files | - submenu -


"#  <get MenuCaption 538>|:tablist : _tabsPane"
	#538; // Go | Tablist...

Code: Select all

"Show Menu" //doesn't always show a menu now...
  if (<curpath> LikeI "<xydata>*) {
    Load 'CEA\XYDATA_Menu.xys',, 'f';
  } elseif (<curpath> LikeI "%windows%*") {
    Echo 'Access Denied!';
  } elseif (<curpath> LikeI 'paper:*') {
    #770;  // View | Paper Folders | - submenu -
  }