Nested favorite folders

[evangelina]

Can we have nested favorite folders like the hamburger icon in the breadcrumb bar?
It might be useful for users with lots of favorite folders like me...

[WirlyWirly]

Alternatively, you could use the popupnested() function to do something similar through scripting, but with a lot more flexibility; A custom menu with your favorite folders and other functions, very handy when assigned to something like a CTB or hotkey.

Here's a template if you're interested.

Code: Select all

/*
A custom context menu for accessing common shortcuts/programs/folders/functions

1 tab per submenu
DISPLAY NAME|DATA (return value)|ICON|STATE

Parameter short-hands start at 0
function(0:=parameter0, 3:=parameter3, 8:=parameter8)
ex: run(0:=command, 3:=show)

*/

$MENUTEMPLATE = <<<MENU
0) Folders||<xyicons>\folders\favorite_folder.ico
    0) Downloads|goto lax("%userreal%\Downloads\")|"%userreal%\Downloads\"
    2) This PC|goto lax("%computer%")|"%computer%"
    3) Recycle|goto lax("%recycler%")|<xyicons>\folders\recyclebin.ico
    4) PaperFolders||:paper
    5) %user%||"%userreal%"
        %user%|goto lax("%userreal%")|"%userreal%"
        Desktop|goto lax("%desktop%")|%desktop%
        Documents|goto lax("%userreal%\Documents\")|%userreal%\Documents\
        Music|goto lax("%userreal%\Music\")|%userreal%\Music\
        Pictures|goto lax("%userreal%\Pictures\")|%userreal%\Pictures\
        Videos|goto lax("%userreal%\Videos\")|%userreal%\Videos\
        -
        AppData|goto lax("%userreal%\AppData\")|<xyicons>\folders\default_folder.ico
    -
    6) XYplorer||"<xypath>"
        0) Scripts|goto "<xyscripts>"|<xyicons>\folders\default_folder.ico
        1) Icons|goto "<xyicons>"|<xyicons>\folders\default_folder.ico
        2) PaperFolders|goto "<xypaper>"|<xyicons>\folders\default_folder.ico
        
1) Sort by...||<xyicons>\other\quickmenu2\sort.ico
    0) Date Modified|Sortby 'Modified', 'clk'|<xyicons>\other\quickmenu2\sortby\datemodified.ico
    1) Name|Sortby 'Name', 'clk'|<xyicons>\other\quickmenu2\sortby\name.ico
    2) Size|Sortby 'Size', 'clk'|<xyicons>\other\quickmenu2\sortby\size.ico
    3) Extension|Sortby 'Ext', 'clk'|<xyicons>\other\quickmenu2\sortby\extension.ico
    4) Type|Sortby 'Type', 'clk'|<xyicons>\other\quickmenu2\sortby\type.ico
    -
    Accessed|Sortby 'Accessed', 'clk'
    Date Created|Sortby 'Created', 'clk'
    Length|Sortby 'len', 'clk'
    Path|Sortby 'Path', 'clk'
    Random|#331
    -
    Folders Apart|#333

MENU;

    // Display the context menu and return the selection
    $command = popupnested($MENUTEMPLATE, 7:="|");

    // Run the selected command or trigger if the data is an id #
    if ($command && !regexmatches($command, '^\#\d+$')) { load $command,, s; }