Collect and paste

Discuss and share scripts and script files...
RalphM
Posts: 1932
Joined: 27 Jan 2005 23:38
Location: Cairns, Australia

Re: Collect and paste

Post by RalphM »

Just stumbled upon this:
Are the pre-function versions of scripting commands as "getkey" still supported?
It seems so, since the script still works but uses the old way...
Ralph :)
(OS: W11 22H2 Home x64 - XY: Current beta - Office 2019 32-bit - Display: 1920x1080 @ 125%)

serendipity
Posts: 3358
Joined: 07 May 2007 18:14
Location: NJ/NY

Re: Collect and paste

Post by serendipity »

RalphM wrote:Just stumbled upon this:
Are the pre-function versions of scripting commands as "getkey" still supported?
It seems so, since the script still works but uses the old way...
Yup, i use the old way for "getkey" because it compliments "setkey" in its syntax. Its somewhat user friendly to me, as you can copy getkey line and paste it elsewhere and change the first alphabet from "g" to "s" to make it setkey.

lukescammell
Posts: 744
Joined: 28 Jul 2006 13:15
Location: Kent, UK
Contact:

Re: Collect and paste

Post by lukescammell »

lukescammell wrote:When I use the UDC to collect a file in the list view, the list view loses focus and the script in the catalogue gets focus. Is there any way to stop this happening?
Any ideas on this one?
Used to update to the latest beta every day. Now I have children instead…
Windows 10 Pro x64 (everywhere except phone…)

serendipity
Posts: 3358
Joined: 07 May 2007 18:14
Location: NJ/NY

Re: Collect and paste

Post by serendipity »

lukescammell wrote:
lukescammell wrote:When I use the UDC to collect a file in the list view, the list view loses focus and the script in the catalogue gets focus. Is there any way to stop this happening?
Any ideas on this one?
Yup, remove this line towards the end of each script:
focus c;

lukescammell
Posts: 744
Joined: 28 Jul 2006 13:15
Location: Kent, UK
Contact:

Re: Collect and paste

Post by lukescammell »

Ah, marvellous! Seems odd to have it in there anyway... I suppose if you're using it from the catalogue... Can a script tell how it's been activated and therefore only fire the focus depending on where it was activated from?
Used to update to the latest beta every day. Now I have children instead…
Windows 10 Pro x64 (everywhere except phone…)

serendipity
Posts: 3358
Joined: 07 May 2007 18:14
Location: NJ/NY

Re: Collect and paste

Post by serendipity »

lukescammell wrote: Perhaps a message to the status bar could be made, such as "5 new items collected"?
There is such a message already in status bar. Should say for eg: Items collected=3 (Total=5). doesn't it?
lukescammell wrote:Can a script tell how it's been activated and therefore only fire the focus depending on where it was activated from?
Yes, "getinfo ("FocusedControl");" will tell where the focus is and one can change the script based on this info. What exactly do you expect happen?

lukescammell
Posts: 744
Joined: 28 Jul 2006 13:15
Location: Kent, UK
Contact:

Re: Collect and paste

Post by lukescammell »

serendipity wrote:
lukescammell wrote: Perhaps a message to the status bar could be made, such as "5 new items collected"?
There is such a message already in status bar. Should say for eg: Items collected=3 (Total=5). doesn't it?
You're quite correct, I must have been temporarily blind or something, apologies.
serendipity wrote:
lukescammell wrote:Can a script tell how it's been activated and therefore only fire the focus depending on where it was activated from?
Yes, "getinfo ("FocusedControl");" will tell where the focus is and one can change the script based on this info. What exactly do you expect happen?
Well I just expect to to go back to where the focus was when you fire the script and the "focus c;" thing was making it always go to the catalogue, even though I was firing the script from the list view using a UDC
Used to update to the latest beta every day. Now I have children instead…
Windows 10 Pro x64 (everywhere except phone…)

aimy
Posts: 181
Joined: 26 Feb 2007 15:44

Re: Collect and paste

Post by aimy »

I cannot access http://88.191.26.34/XYscripts/download/ link.

May I have the latest update for this script please??

Thanks a lot.

zer0
Posts: 2673
Joined: 19 Jan 2009 20:11

Re: Collect and paste

Post by zer0 »

jacky doesn't maintain that site any more and has not posted here in quite some time. Your chances are slim, sorry.
Reporting a bug? Have a wish? Got a question? Use search - View roadmap - FAQs: Forum + XY site
Windows 7/10
Always using the latest stable two-decimal build

aimy
Posts: 181
Joined: 26 Feb 2007 15:44

Re: Collect and paste

Post by aimy »

zer0 wrote:jacky doesn't maintain that site any more and has not posted here in quite some time. Your chances are slim, sorry.
dont u have it yourself? the latest one? :)

Stefan
Posts: 1360
Joined: 18 Nov 2008 21:47
Location: Europe

Re: Collect and paste

Post by Stefan »

As far as i see the latest one is the one posted above > http://www.xyplorer.com/xyfc/viewtopic. ... 695#p33695

But that was posted: 08 Jun 2009 and may be "out of syntax" due some changes in scripting rules...

serendipity
Posts: 3358
Joined: 07 May 2007 18:14
Location: NJ/NY

Re: Collect and paste

Post by serendipity »

Yes, just one thing changed (the trailing delimiters "|" were removed in 9.40.0007) and I have fixed it. Below is the updated script. :D. I briefly tried it and it seems to work for me. Let me know if there are issues.

Code: Select all

//Collect
"Collect items : collect"
   getkey $Items, "items", "collected", "collect.ini";
   getkey $Count, "count", "collected", "collect.ini";
   focus;
   
   $SelectedItemsPath= getinfo ("SelectedItemsPathNames", "|")."|";
   $CountSelectedItems= getinfo ("CountSelected");
     
   set $Items, $SelectedItemsPath.$Items;
   incr $Count, $Count, $CountSelectedItems;
      
   setkey $Items, "items", "collected", "collect.ini"; 
   setkey $Count, "count", "collected", "collect.ini"; 
   status "Items collected=$CountSelectedItems (Total=$Count)", BF0000, progress;   
   focus c;
- 
"Copy items to : copyto"
   getkey $Items, "items", "collected", "collect.ini";
   getkey $Count, "count", "collected", "collect.ini";
   replace $ForTextMessage, $Items, "|",<crlf>;
   text $ForTextMessage, , , "You have collected $Count items, you can choose where to copy them next.",w;
   inputfolder $Path, <curpath>, Choose folder to copy items to;
   copyto "$Path", $Items;
   setkey , "items", "collected", "collect.ini";
   setkey , "count", "collected", "collect.ini";
   status "$Count Items Copied", , Ready;
   focus c;

  
"Move items to : moveto"
   getkey $Items, "items", "collected", "collect.ini";
   getkey $Count, "count", "collected", "collect.ini";
   replace $ForTextMessage, $Items, "|",<crlf>;
   text $ForTextMessage, , , "You have collected $Count items, you can choose where to Move them next.",w;
   inputfolder $Path, <curpath>, Choose folder to Move items to;
   moveto "$Path", $Items;
   setkey , "items", "collected", "collect.ini";
   setkey , "count", "collected", "collect.ini";
   status "$Count Items Moved", , Ready;
   focus c;
   
"Backup items to : backupto"
   getkey $Items, "items", "collected", "collect.ini";
   getkey $Count, "count", "collected", "collect.ini";
   replace $ForTextMessage, $Items, "|",<crlf>;
   text $ForTextMessage, , , "You have collected $Count items, you can choose where to Back them up next.",w;
   inputfolder $Path, <curpath>, Choose folder to Backup items to;
   backupto "$Path", $Items;
   setkey , "items", "collected", "collect.ini";
   setkey , "count", "collected", "collect.ini";
   status "$Count Items Backedup", , Ready;
   focus c;
-
"Show collected items : show"
   getkey $Items, "items", "collected", "collect.ini";
   getkey $Count, "count", "collected", "collect.ini";
   replace $ForTextMessage, $Items, "|",<crlf>;
   incr $Count, $Count,0;
   
   //text $ForTextMessage, , , "You have collected $Count items",w;
   
   // Cancel = same message => no modification
   $Response = input("You have collected $Count items (you can add/remove items)", , $ForTextMessage, w, $ForTextMessage);
   
   // Update $Items
      replace $Items, $Response, "<crlf>", "|";
         
   // Update $Count
   regexreplace $Tokens, $Items, "[^|]";
   strlen $Count, $Tokens;
   
   setkey $Items, "items", "collected", "collect.ini";
   setkey $Count, "count", "collected", "collect.ini";


"Empty collected items : empty"
   setkey 1, "exists", "tmp", "collect.ini";
   self $path, path;
   delete 0, 0, "$path\collect.ini";
   status "Collected items emptied", , alert;
   focus c;
- 

"Edit script : edit"
   self $ScriptFile, file;
   Open $ScriptFile,w;
-
"Cancel"

aimy
Posts: 181
Joined: 26 Feb 2007 15:44

Re: Collect and paste

Post by aimy »

Thank you very much serendipity.. :)

Ermmm.. But actually what i've been looking for is for this script...

Code: Select all

/*	CollectItems
	
	v0.01.0003	2009.01.27	XY v7.90.0021	CJ v0.01.0004
		+ "Edit Configuration File" now done directly inside XY
	
	v0.01.0002	2009.01.15	XY v7.90.0021	CJ v0.01.0004
		! Added setting to allow recursion!
	
	v0.01.0001	2009.01.11	XY v7.90.0021	CJ v0.01.0003
		+ Show All Collections : switched to HTML
	
	v0.01.0000	2008.11.30	XY v7.90.0021	CJ v0.01.0001
		+ first "new" release
*/
"_noSel"
	global $XYS_name;
	status "$XYS_name: No items selected !",,alert;
"[ ACTIVE ]"
-
"&Add Selected Items To Collection : AddToCollection"
	sub _ensureXY;
	sub (getinfo("CountSelected") > 0) ? "_addToCol" : "_noSel";
"_addToCol"
	global $XYS_name, $CI_colname, $CI_list, $CI_collection;
	self $base, base;
	setting "AllowRecursion", 1;
	$CI_colname = ($CI_colname == "") ? "Active" : $CI_colname;
	getkey $CI_collection, "$CI_colname", "Collections", "$base.ini";
	replace $CI_list, report('{Fullname}|', 1), "[", "[[]"; // deal with brackets in filename
	sub ($CI_list == "") ? "_nothing" : "_addSel";
	setkey $CI_collection, "$CI_colname", "Collections", "$base.ini";
	status "$XYS_name: Selected items added to ".(($CI_colname == "Active") ? "active collection" : "collection ""$CI_colname""");
"_addSel"
	global $CI_list, $CI_collection;
	strpos $p, $CI_list, "|";
	substr $item, $CI_list, 0, $p;
	substr $CI_list, $CI_list, $p + 1;
	//
	strpos $p, $CI_collection, $item;
	$CI_collection = ($p == -1) ? "$CI_collection$item|" : $CI_collection;
	//
	end ($CI_list == ""),,1;
	sub _addSel;
"&Remove Selected Items From Collection : RemoveFromCollection"
	sub _ensureXY;
	sub (getinfo("CountSelected") > 0) ? "_remFromCol" : "_noSel";
"_remFromCol"
	global $XYS_name, $CI_colname, $CI_list, $CI_collection;
	self $base, base;
	setting "AllowRecursion", 1;
	$CI_colname = ($CI_colname == "") ? "Active" : $CI_colname;
	getkey $CI_collection, "$CI_colname", "Collections", "$base.ini";
	replace $CI_list, report('{Fullname}|', 1), "[", "[[]"; // deal with brackets in filename
	sub ($CI_list == "") ? "_nothing" : "_remSel";
	setkey $CI_collection, "$CI_colname", "Collections", "$base.ini";
	status "$XYS_name: Selected items removed from ".(($CI_colname == "Active") ? "active collection" : "collection ""$CI_colname""");
"_remSel"
	global $CI_list, $CI_collection;
	strpos $p, $CI_list, "|";
	substr $item, $CI_list, 0, $p;
	substr $CI_list, $CI_list, $p + 1;
	//
	strpos $p, $CI_collection, $item;
	strlen $l, $item;
	substr $bef, $CI_collection, 0, $p;
	substr $aft, $CI_collection, $p + $l + 1;
	$CI_collection = ($p == -1) ? $CI_collection : "$bef$aft";
	//
	end ($CI_list == ""),,1;
	sub _remSel;
-
"_noItemsInCollection"
	global $XYS_name;
	status "$XYS_name: No items found in collection",,stop;
	msg "No items found in collection !";
"&Move Collected Items Here : MoveCollectedHere"
	global $XYS_name, $CI_colname;
	sub _ensureXY;
	self $file, file;
	self $path, path;
	self $base, base;
	$CI_colname = ($CI_colname == "") ? "Active" : $CI_colname;
	getkey $collection, "$CI_colname", "Collections", "$base.ini";
	substr $collection, $collection, 0, -1;
	replace $collection, $collection, "'", "''";
	load (($collection == "") ? "load ""$file"", ""_noItemsInCollection"";" : "moveto ""<curpath>"", '$collection'; setkey """", ""$CI_colname"", ""Collections"", ""$path\$base.ini"";"),,s;
	end $collection == "",,1;
	status "$XYS_name: Items from ".(($CI_colname == "Active") ? "active collection" : "collection ""$CI_colname""")." moved here";
"&Copy Collected Items Here : CopyCollectedHere"
	global $XYS_name, $CI_colname;
	sub _ensureXY;
	self $file, file;
	self $path, path;
	self $base, base;
	$CI_colname = ($CI_colname == "") ? "Active" : $CI_colname;
	getkey $collection, "$CI_colname", "Collections", "$base.ini";
	substr $collection, $collection, 0, -1;
	replace $collection, $collection, "'", "''";
	load (($collection == "") ? "load ""$file"", ""_noItemsInCollection"";" : "copyto ""<curpath>"", '$collection';"),,s;
	end $collection == "",,1;
	status "$XYS_name: Items from ".(($CI_colname == "Active") ? "active collection" : "collection ""$CI_colname""")." copied here";
"&Delete Collected Items : DeleteCollected"
	global $XYS_name, $CI_colname;
	sub _ensureXY;
	self $file, file;
	self $path, path;
	self $base, base;
	$CI_colname = ($CI_colname == "") ? "Active" : $CI_colname;
	getkey $collection, "$CI_colname", "Collections", "$base.ini";
	substr $collection, $collection, 0, -1;
	replace $collection, $collection, "'", "''";
	load (($collection == "") ? "load ""$file"", ""_noItemsInCollection"";" : "delete 0, 1, '$collection'; setkey """", ""$CI_colname"", ""Collections"", ""$path\$base.ini"";"),,s;
	end $collection == "",,1;
	status "$XYS_name: Items from ".(($CI_colname == "Active") ? "active collection" : "collection ""$CI_colname""")." deleted";
-
"&Edit Collection... : _EditCollection"
	global $XYS_name, $CI_colname;
	sub _ensureXY;
	self $base, base;
	$CI_colname = ($CI_colname == "") ? "Active" : $CI_colname;
	getkey $collection, "$CI_colname", "Collections", "$base.ini";
	replace $collection, $collection, "|", <crlf>;
	status "$XYS_name: Editing items in ".(($CI_colname == "Active") ? "active collection" : "collection ""$CI_colname""");
	input $collection, "Editing: " . (($CI_colname == "Active") ? "Active Collection" : "Collection ""$CI_colname"""), $collection, m;
	replace $collection, $collection, <crlf>, "|";
	setkey $collection, $CI_colname, "Collections", "$base.ini";
	status "$XYS_name: ".(($CI_colname == "Active") ? "Active collection" : "Collection ""$CI_colname""")." saved";
"&Delete Collection... : DeleteCollection"
	global $XYS_name, $CI_colname;
	sub _ensureXY;
	self $path, path;
	self $base, base;
	$CI_colname = ($CI_colname == "") ? "Active" : $CI_colname;
	load ( (confirm("Do you want to delete the ".(($CI_colname == "Active") ? "active collection" : "collection ""$CI_colname""")." ?")) ? ('setkey "", "'.$CI_colname.'", "Collections", "'.$path.'\'.$base.'.ini"; status "'.$XYS_name.': '.(($CI_colname == "Active") ? "Active Collection" : "Collection """"$CI_colname""""").' deleted";') : 'call'),,s;
-
-
"[ GLOBAL ]"
"_global"
	global $CI_script, $CI_flg;
	self $path, path;
	self $file, file;
	self $base, base;
	// getting the list of collections -- reading the INI
	$data = readfile("$path\$base.ini");
	strpos $p, $data, "[Collections]";
	// going inside the list of collections
	strpos $p, $data, <crlf>, $p;
	// and assuming there's no more settings after!! (yeah, I know...)
	substr $data, $data, $p + 2;
	// putting all names on one line
	regexreplace $data, $data, "\r", "";
	regexreplace $data, $data, "\n", "/";
	// and turning it into a selection-menu
	regexreplace $data, $data, "(.+?)=.+?/", '"$1" global $CI_colname; $CI_colname = "$1"; load "'.$file.'", "'.$CI_script.'";'.<crlf>;
	$data = ($data == "") ? """(no collections found)""<crlf>" : $data;
	$data = $data . (($CI_flg == 1) ? "-<crlf>""Create new collection..."" load ""$file"", ""_createNewCollection""; <crlf>" : "");
	load "$data<crlf>-<crlf>""<< Back"" load ""$file"",*;",,s;
"_createNewCollection"
	global $XYS_name, $CI_colname, $CI_script;
	self $base, base;
	status "$XYS_name: Creating a new collection...",,progress;
	$CI_colname = input("Enter the collection name",,"New Collection",,"::abort::"); // no, you can't name your collection "::abort::" Sucks, but that's life!
	sub ($CI_colname == "::abort::") ? "_abortNewCollection" : "_nothing";
	getkey $check, $CI_colname, "Collections", "$base.ini";
	$check = ($check == "") ? 1 : confirm("There is already a collection ""$CI_colname"" -- Do you want to continue anyway ?");
	// just to show a nice statusbar message instead of a popup...
	sub ($check == 0) ? "_abortNewCollection" : "_nothing";
	// ...in case we stop there
	end ($check == 0),,1;
	status "$XYS_name: Collection ""$CI_colname"" created";
	sub $CI_script;
"_abortNewCollection"
	global $XYS_name;
	status "$XYS_name: Operation aborted, no collection created",,alert;
	end 1;
-
"&Add Selected Items To A Collection... : AddToCollectionGlobal"
	global $CI_script, $CI_flg;
	sub _ensureXY;
	$CI_script = "AddToCollection";
	$CI_flg = 1;
	sub _global;
"&Remove Selected Items From A Collection... : _RemoveFromCollectionGlobal"
	global $CI_script, $CI_flg;
	sub _ensureXY;
	$CI_script = "RemoveFromCollection";
	$CI_flg = 0;
	sub _global;
"- : _sep"
"&Move Here Items From A Collection... : _MoveCollectedHereGlobal"
	global $CI_script, $CI_flg;
	sub _ensureXY;
	$CI_script = "MoveCollectedHere";
	$CI_flg = 0;
	sub _global;
"&Copy Here Items From A Collection... : _CopyCollectedHereGlobal"
	global $CI_script, $CI_flg;
	sub _ensureXY;
	$CI_script = "CopyCollectedHere";
	$CI_flg = 0;
	sub _global;
"&Delete Items From A Collection... : _DeleteCollectedGlobal"
	global $CI_script, $CI_flg;
	sub _ensureXY;
	$CI_script = "DeleteCollected";
	$CI_flg = 0;
	sub _global;
"- : _sep"
"&Edit A Collection... : _EditCollectionGlobal"
	global $CI_script, $CI_flg;
	sub _ensureXY;
	$CI_script = "_EditCollection";
	$CI_flg = 1;
	sub _global;
"&Delete A Collection... : _DeleteCollectionGlobal"
	global $CI_script, $CI_flg;
	sub _ensureXY;
	$CI_script = "DeleteCollection";
	$CI_flg = 0;
	sub _global;
-
"&Show All Collections... : ShowAllCollections"
	global $XYS_name, $CI_results, $CJ_tmp, $CJ_title, $CJ_html;
	sub _ensureXY;
	self $file, file;
	self $path, path;
	self $base, base;
	$data = readfile("$path\$base.ini");
	strpos $p, $data, "[Collections]";
	strpos $p, $data, <crlf>, $p;
	substr $data, $data, $p + 2;
	regexreplace $data, $data, "\r", "";
	regexreplace $data, $data, "\n", "/";
	regexreplace $nb, $data, "(.+?)=.+?/", "+";
	regexreplace $data, $data, "(.+?)=.+?/", 'global $CI_colname; $CI_colname = "$1"; load "'.$file.'", "_ListCollection"; ';
	strlen $nb, $nb;
	load (($nb == 0) ? ('status "'.$XYS_name.': No collections found",,stop; end 1, "No collections found !"; ') : $data),,s;
	status "$XYS_name: Showing All Collections ($nb)";
	$CJ_title = "$XYS_name: Showing All Collections ($nb)";
	$CJ_html = $CI_results;
	$CJ_tmp = "_ShowHTML";
	sub _callCommonJacky;
	$script = ($CJ_html == "") ? 'call' : urldecode($CJ_html);
	load $script,,s;
"_ListCollection"
	global $CI_results, $CI_colname;
	self $base, base;
	getkey $collection, "$CI_colname", "Collections", "$base.ini";
	regexreplace $collection, "$collection", "(.+?)\|", "<li><a OnMouseover='window.status=""Click to browse to item""; return true;' OnMouseout=""window.status=''; return true;"" href='xys:goto ""$1"";'>$1</a></li>";
	$CI_results = $CI_results . "<h2>".(($CI_colname == "Active") ? "Active Collection" : "Collection ""$CI_colname""")."</h2><ul>$collection</ul>";
-
-
"[ CollectItems ]"
-
"_ensureXY"
	global $XYS_name, $XYS_file;
	self $XYS_file, file;
	getkey $XYS_name, "name", "Internal", $XYS_file;
	getkey $xyreq, "requiredXY", "Internal", $XYS_file;
	end (compare(<xyver>, $xyreq, v) >= 0),,1;
	msg "WARNING: This version of $XYS_name requires XYplorer v$xyreq in order to work properly.<br><br>You are currently running an older version (<xyver>), are you sure you want to continue anyway ?<br><br>Note that this might lead to errors / unexpected results.", 1;
"&About CollectItems : About"
	global $XYS_name, $CJ_tmp;
	sub _ensureXY;
	self $file, file;
	self $path, path;
	self $base, base;
	getkey $curver, "version", "Internal", $file;
	getkey $xyreq, "requiredXY", "Internal", $file;
	getkey $cjreq, "requiredCJ", "Internal", $file;
	getkey $cjver, "version", "Internal", "$path\common-jacky.xys";
	status "$XYS_name: version $curver";
	//
	$data = readfile("$path\$base.ini");
	strpos $p, $data, "[Collections]";
	strpos $p, $data, <crlf>, $p;
	substr $data, $data, $p + 2;
	regexreplace $data, $data, "\r", "";
	regexreplace $data, $data, "\n", "/";
	regexreplace $nb, $data, "(.+?)=.+?/", "+";
	regexreplace $data, $data, "(.+?)=.+?/", "$1, ";
	strlen $nb, $nb;
	substr $data, $data, 0, -2;
	$list = ($nb == 0) ? "No collections yet." : (($nb == 1) ? "One collection: $data" : "$nb collections: $data");
	//
	$CJ_tmp = "_getXyauState";
	sub _callCommonJacky;
	$CJ_tmp = ($CJ_tmp == "_getXyauState") ? "Unable to get XYplorer Automatic Updater integration state -- requires common-jacky.xys" : $CJ_tmp;
	//
	msg "$XYS_name -- version $curver<br>Requires XYplorer $xyreq (Running: <xyver>)<br>Requires common-jacky $cjreq".(($cjver == '') ? ' (Not Found!)' : " (Running $cjver)")."<br><br>This script: $file<br>Configuration: $path\$base.ini<br><br>$list<br><br>$CJ_tmp";
	load *;
"Change&log of CollectItems : _AutoChangelog"
	global $CJ_tmp;
	sub _ensureXY;
	$CJ_tmp = "_AutoChangelogHTML";
	sub _callCommonJacky;
	load *;
"&Edit Configuration File... : _EditINI"
	global $XYS_name;
	sub _ensureXY;
	self $path, path;
	self $base, base;
	$file = "$path\$base.ini";
	status "$XYS_name: Editing $file",,progress;
	status writefile($file, input("$XYS_name: Editing Configuration File",,readfile($file), w,,800, 600)) ? "$XYS_name: File saved" : "$XYS_name: Error writing file";
"- : _sep"
"Chec&k for updates of CollectItems... : _CheckForAutoUpdates"
	global $CJ_tmp;
	sub _ensureXY;
	$CJ_tmp = "_CheckForAutoUpdates";
	sub _callCommonJacky;
	load *;
"&Install CollectItems support in XYplorer Automatic Updater... : _InstallInXYAU"
	global $CJ_tmp;
	sub _ensureXY;
	$CJ_tmp = "_InstallInXYAU";
	sub _callCommonJacky;
	load *;
"_callCommonJacky"
	global $CJ_tmp;
	self $file, file;
	self $path, path;
	getkey $cj_req, "requiredCJ", "Internal", $file;
	getkey $cj_ver, "version", "Internal", "common-jacky.xys";
	end $cj_ver == "", ($CJ_tmp == '_getXyauState') ? '' : "In order to accomplish the desired operation, you need to have the ""library"" common-jacky.xys installed -- Please download the script file and put it in the same folder as this script file ($path\).", 1;
	end (compare($cj_ver, $cj_req, v) == -1), "In order to accomplish the desired operation, you need to have the ""library"" common-jacky.xys v$cj_req or more installed, your current version is v$cj_ver -- Please update to the latest version.", 1;
	load "common-jacky", "$CJ_tmp";
-
"Show &Full Menu... : ShowFullMenu"
	load *,*;
"Show Standard &Menu... : _ShowMenu"
	load *;
"Cancel : nothing"
"_nothing"
"_settings"
	[Internal]
	name="CollectItems"
	version="0.01.0003"
	requiredXY="7.90.0021"
	requiredCJ="0.01.0004"
	Url="http://88.191.26.34/XYscripts/download/"
If I'm not mistaken, last time, it was from you who introduced me the script above, don't you?

Anyway, your script is neat and simple. It's just that I don't like the idea of having to select the final output folder via pop-up window instead of the normal paste into the current open folder. Don't you think so?

Thank you.

serendipity
Posts: 3358
Joined: 07 May 2007 18:14
Location: NJ/NY

Re: Collect and paste

Post by serendipity »

aimy wrote:Thank you very much serendipity.. :)

Ermmm.. But actually what i've been looking for is for this script...

Code: Select all

/*	CollectItems
	
	
If I'm not mistaken, last time, it was from you who introduced me the script above, don't you?

Anyway, your script is neat and simple. It's just that I don't like the idea of having to select the final output folder via pop-up window instead of the normal paste into the current open folder. Don't you think so?

Thank you.
Hi, the above script is not from me, i think its from Jacky. But its very easy to implement straightforward copy instead of the pop-up style where you can choose to copy/move/backup. i will implement it when i have time.

serendipity
Posts: 3358
Joined: 07 May 2007 18:14
Location: NJ/NY

Re: Collect and paste

Post by serendipity »

Updated collect & paste script, now called Collect v2:
-option to directly copy/move/backup items to current folder. Previously you always had to choose a location first.
- pop-up menu has icons now.
-conditional menu (when no items collected menu is shorter)

I have attached a basket icon (free) if you want to use, else default icon for collect items is sticky button.
Download:
Collect v2.xys
(6.11 KiB) Downloaded 248 times
basket icon:
basket.zip
(2.61 KiB) Downloaded 236 times

Post Reply