request:select files by type , move each type to new folde

Discuss and share scripts and script files...
Post Reply
yusef88
Posts: 1123
Joined: 28 Jan 2013 03:50
Location: Windows 8.1 32-bit

request:select files by type , move each type to new folde

Post by yusef88 »

hi dear members :)
select files by type and move each type to new folder with customized name,
i need a basic script and if possible i'll add desired extension
example:
select all "flv , mp4" and move to new folder video
select all "jpg , png" and move o new folder picture
select files has no extension to new folder undefined
is that possible?
========
"Video|Video Files" {:Video}
"Image|Image Files" {:Image}
those filter can't help?
======
i want add date to folder name video2013-12-21

binocular222
Posts: 1416
Joined: 04 Nov 2008 05:35
Location: Hanoi, Vietnam

Re: request:select files by type , move each type to new fol

Post by binocular222 »

Do visual filters such as:

Code: Select all

*.flv|*.mp4
I'm a casual coder using AHK language. All of my xys scripts:
http://www.xyplorer.com/xyfc/viewtopic. ... 243#p82488

yusef88
Posts: 1123
Joined: 28 Jan 2013 03:50
Location: Windows 8.1 32-bit

Re: request:select files by type , move each type to new fol

Post by yusef88 »

it will be a convenient way to sort files by type into folders by one click especially when it becomes an iterative process

highend
Posts: 13274
Joined: 06 Feb 2011 00:33

Re: request:select files by type , move each type to new fol

Post by highend »

Edit the variables in the "_Initialize" section...

Code: Select all

// Move specific filetypes into specific folders
"_Initialize"
    global $extVideo, $videoFolder, $extImage, $imageFolder, $undefinedFolder;

    $extVideo     = "flv,mp4,avi";
    $videoFolder  = "video";
    $extImage     = "jpg,png";
    $imageFolder  = "picture";
    $undefinedFolder = "undefined";


"_LoopFiles"
    global $selExt, $dstFolder;
    $dstFolder = "$dstFolder" . "<date yyyy-mm-dd>";
    setting "BackgroundFileOps", 0;

    $filesToMove = "";
    foreach($item, $selExt, ",") {
        if ($item == "none") {
            $noExtensionFiles = listfolder(, "*", 1, "|");
            foreach($noExtFile, $noExtensionFiles, "|") {
                if (getpathcomponent($noExtFile, "ext") == "") {
                    $filesToMove = $filesToMove . $noExtFile . "|";
                }
            }
        } else {
            $filesToMove = $filesToMove . listfolder(, "*.$item", 1, "|") . "|";
        }
    }
    $filesToMove = formatlist($filesToMove, "e", "|");
    if (exists("<curpath>\$dstFolder") == 0) {
        new("<curpath>\$dstFolder", "dir");
    }
    moveto "<curpath>\$dstFolder", $filesToMove;


"Move video files"
    global $extVideo, $videoFolder, $selExt, $dstFolder;
    $selExt = $extVideo;
    $dstFolder = $videoFolder;
    sub "_LoopFiles";

"Move image files"
    global $extImage, $imageFolder, $selExt, $dstFolder;
    $selExt = $extImage;
    $dstFolder = $imageFolder;
    sub "_LoopFiles";

"Move undefined files"
    global $undefinedFolder, $selExt, $dstFolder;
    $selExt = "none";
    $dstFolder = $undefinedFolder;
    sub "_LoopFiles";
One of my scripts helped you out? Please donate via Paypal

yusef88
Posts: 1123
Joined: 28 Jan 2013 03:50
Location: Windows 8.1 32-bit

Re: request:select files by type , move each type to new fol

Post by yusef88 »

so genius script :appl: thanks from the heart, highend :D

Post Reply