Page 1 of 1
request:select files by type , move each type to new folde
Posted: 21 Dec 2013 03:47
by yusef88
hi dear members 
select files by type and move each type to new folder with customized name,
i need a basic script and if possible i'll add desired extension
example:
select all
"flv , mp4" and move to new folder
video
select all
"jpg , png" and move o new folder
picture
select
files has no extension to new folder
undefined
is that possible?
========
"Video|Video Files" {:Video}
"Image|Image Files" {:Image}
those filter can't help?
======
i want add date to folder name
video2013-12-21
Re: request:select files by type , move each type to new fol
Posted: 21 Dec 2013 08:25
by binocular222
Do visual filters such as:
Re: request:select files by type , move each type to new fol
Posted: 21 Dec 2013 09:34
by yusef88
it will be a convenient way to sort files by type into folders by one click especially when it becomes an iterative process
Re: request:select files by type , move each type to new fol
Posted: 21 Dec 2013 11:09
by highend
Edit the variables in the "_Initialize" section...
Code: Select all
// Move specific filetypes into specific folders
"_Initialize"
global $extVideo, $videoFolder, $extImage, $imageFolder, $undefinedFolder;
$extVideo = "flv,mp4,avi";
$videoFolder = "video";
$extImage = "jpg,png";
$imageFolder = "picture";
$undefinedFolder = "undefined";
"_LoopFiles"
global $selExt, $dstFolder;
$dstFolder = "$dstFolder" . "<date yyyy-mm-dd>";
setting "BackgroundFileOps", 0;
$filesToMove = "";
foreach($item, $selExt, ",") {
if ($item == "none") {
$noExtensionFiles = listfolder(, "*", 1, "|");
foreach($noExtFile, $noExtensionFiles, "|") {
if (getpathcomponent($noExtFile, "ext") == "") {
$filesToMove = $filesToMove . $noExtFile . "|";
}
}
} else {
$filesToMove = $filesToMove . listfolder(, "*.$item", 1, "|") . "|";
}
}
$filesToMove = formatlist($filesToMove, "e", "|");
if (exists("<curpath>\$dstFolder") == 0) {
new("<curpath>\$dstFolder", "dir");
}
moveto "<curpath>\$dstFolder", $filesToMove;
"Move video files"
global $extVideo, $videoFolder, $selExt, $dstFolder;
$selExt = $extVideo;
$dstFolder = $videoFolder;
sub "_LoopFiles";
"Move image files"
global $extImage, $imageFolder, $selExt, $dstFolder;
$selExt = $extImage;
$dstFolder = $imageFolder;
sub "_LoopFiles";
"Move undefined files"
global $undefinedFolder, $selExt, $dstFolder;
$selExt = "none";
$dstFolder = $undefinedFolder;
sub "_LoopFiles";
Re: request:select files by type , move each type to new fol
Posted: 21 Dec 2013 21:48
by yusef88
so genius script 
thanks from the heart, highend 